Generic m3ter API Invocable Action

m3.M3terGenericAPIService.GenericAPIRequest request = new m3.M3terGenericAPIService.GenericAPIRequest();
request.operation = 'GET';
request.endpoint = 'accounts';
request.queryParams = '{"pageSize":"50"}';   // optional, JSON object of string values

List<m3.M3terGenericAPIService.APITransportResult> results =
    m3.M3terGenericAPIService.callM3terAPI(
        new List<m3.M3terGenericAPIService.GenericAPIRequest>{ request }
    );

m3.M3terGenericAPIService.APITransportResult result = results[0];
if (result.success) {
    Map<String, Object> body = (Map<String, Object>) JSON.deserializeUntyped(result.responseBody);
    if (result.hasMoreResults) { /* result.nextToken */ }
} else {
    // result.httpStatusCode, result.errorMessage
}

//Create an m3ter Balance for an Account, then post a Transaction against it 

String accountId    = 'bfc500d9-0427-4d80-9ddb-03e6140970dc';
String currencyCode = 'USD';
String startDate    = '2026-01-01T00:00:00.000Z';
String endDate      = '2026-12-31T00:00:00.000Z';
Decimal initialAmount = 1000;

// ── Step 1: create the Balance 
m3.M3terGenericAPIService.GenericAPIRequest balanceReq =
    new m3.M3terGenericAPIService.GenericAPIRequest();
balanceReq.operation = 'POST';
balanceReq.endpoint = 'balances';
String balanceCode = System.UUID.randomUUID().toString();
balanceReq.requestBody = JSON.serialize(new Map<String, Object>{
    'accountId'   => accountId,
    'currency'    => currencyCode,
    'startDate'   => startDate,
    'endDate'     => endDate,
    'code'        => balanceCode,
    'name'        => 'Prepaid balance created via generic API service'
});

m3.M3terGenericAPIService.APITransportResult balanceRes =
    m3.M3terGenericAPIService.callM3terAPI(
        new List<m3.M3terGenericAPIService.GenericAPIRequest>{ balanceReq }
    )[0];

if (!balanceRes.success) {
    System.debug(LoggingLevel.ERROR,
        'Balance create failed (' + balanceRes.httpStatusCode + '): ' + balanceRes.errorMessage);
    return;
}

Map<String, Object> balanceBody =
    (Map<String, Object>) JSON.deserializeUntyped(balanceRes.responseBody);
String balanceId = (String) balanceBody.get('id');
System.debug('Created Balance: ' + balanceId);

// Step 2: post a Transaction against the new Balance 
// The endpoint is built from the id returned by Step 1 

m3.M3terGenericAPIService.GenericAPIRequest txReq =
    new m3.M3terGenericAPIService.GenericAPIRequest();
txReq.operation = 'POST';
txReq.endpoint = 'balances/' + balanceId + '/transactions';
txReq.requestBody = JSON.serialize(new Map<String, Object>{
    'amount'      => initialAmount,
    'appliedDate' => startDate,
    'currencyPaid'=> currencyCode,
    'transactionTypeId' => 'ca6af083-c94b-47a8-832f-22f17dba7267',    
    'description' => 'Initial funding'
});

m3.M3terGenericAPIService.APITransportResult txRes =
    m3.M3terGenericAPIService.callM3terAPI(
        new List<m3.M3terGenericAPIService.GenericAPIRequest>{ txReq }
    )[0];

if (!txRes.success) {
    // Balance exists but the transaction failed — retry the transaction against
    // balanceId rather than re-creating the balance (that would orphan one in m3ter).
    System.debug(LoggingLevel.ERROR,
        'Balance ' + balanceId + ' created, but transaction failed (' +
        txRes.httpStatusCode + '): ' + txRes.errorMessage);
    return;
}

Map<String, Object> txBody =
    (Map<String, Object>) JSON.deserializeUntyped(txRes.responseBody);
System.debug('Created Transaction: ' + txBody.get('id') + ' against Balance ' + balanceId);